home *** CD-ROM | disk | FTP | other *** search
/ Mac Magazin/MacEasy 32 / Mac Magazin and MacEasy Magazine CD - Issue 32.iso / Grafik & Text / OzTeX3.0 / Metafont / Inputs / ec / exromp.mf < prev    next >
Text File  |  1997-03-16  |  5KB  |  108 lines
  1. % exromp.mf
  2. %
  3. % (c) Copyright 1995, 1996, 1997 J"org Knappen
  4. % (c) Copyright 1990, 1992 Norbert Schwarz
  5. %
  6. % This file is part of ecfonts version 1.0
  7. %
  8. % Please read the files 00readme.txt, 00inst.txt, 00error.txt, and
  9. % copyrite.txt for further information
  10. %
  11. % You find some documentation in ecdoc.tex (needs LaTeX2e)
  12. %
  13. % Content:
  14. %
  15. %  some special roman characters (different from italic variants)
  16. %
  17. %    & ? spanish ?
  18.  
  19. version_check(1,0);  % |version_check| was introduced in dc1.3
  20.  
  21. ecchar "Ampersand";
  22. beginchar("&",14u#,asc_height#,0);
  23. italcorr x_height#*slant-serif_fit# - if serifs: .4u# else: 1.5u# fi;
  24. adjust_fit(0,serif_fit#);
  25. pickup tiny.nib; pos2(slab,-90); x2=4u; bot y2r=-o;
  26. if not hefty:(x,y2l)=whatever[z2r,(w-5u,x_height)]; x2l:=x; fi
  27. if serifs: pos0(fudged.hair,0);
  28.  rt x0r+jut=hround(w-.9u); top y0=x_height;
  29.  pos1(fudged.hair,0); z1=whatever[z0,(.6[x0,x2],0)];
  30.  y1=max(y0-1.5bracket-.2x_height,2/3x_height);
  31.  filldraw stroke z0e---z1e...{left}z2e;  % short diagonal
  32. else: pickup fine.nib; pos1(.25[slab,flare],-15); rt x1r=hround(w-2u);
  33.  y1r=good.y .75[bar_height,x_height]; x1l:=good.x x1l; y1l:=good.y y1l;
  34.  top z2'l=(x2l,tiny.top y2l); bot z2'r=(x2r,tiny.bot y2r);
  35.  filldraw stroke term.e(2',1,right,1,4); fi  % short diagonal and terminal
  36. pickup tiny.nib; numeric slope,theta,reduced_hair;
  37. slope=(h-2vair-slab)/10.5u; theta=angle(-slope,1);
  38. reduced_hair=max(tiny.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
  39. lft x3r=hround .75u; x5=.5[x3r,x6l]; lft x6r=hround .5(w-u);
  40. x3l-x3r=curve-tiny; pos6(reduced_hair,180);
  41. pos5(vair,theta); y5=.5h;
  42. ellipse_set(2l,3l,4l,5l); ellipse_set(2r,3r,4r,5r);
  43. pos7(vair,270); top y7l=h+o; x7=.45[x6r,x8r];
  44. pos8(fudged.stem,30); x8l=good.x(x8l+3.5u-x8); y8r=y6;
  45. ellipse_set(7l,6l,5',5l);
  46. filldraw stroke z2e{left}...z3e{up}...z4e---z5e...{up}z6e
  47.  ...z7e{left}...z8e{down};  % bowls
  48. pos10(slab,90); x10=w-3.5u; bot y10l=-o;
  49. pos9(fudged.stem,angle(z8-z10)-90);
  50. z9=.5[z8,z10]+(1.75u,0) rotated(angle(z8-z10)+90);
  51. filldraw stroke z8e{down}...z9e{z10-z8}...{right}z10e;  % long diagonal
  52. if serifs: pickup crisp.nib; pos10'(slab,90); z10'=z10;
  53.  pos11(fudged.hair,180); rt x11l=hround(w-u); y11=.5bar_height;
  54.  filldraw stroke z10'e{right}...{up}z11e;  % terminal
  55.  numeric inner_jut; if rt x6l+.5u<lft x0l-1.5jut: inner_jut=1.5jut;
  56.  else: rt x6l+.5u=lft x0l-inner_jut; fi
  57.  dish_serif(0,1,a,.6,inner_jut,b,.5,jut)(dark);  % serif
  58. else: pickup fine.nib; pos10'(slab,90); z10'=z10;
  59.  pos11(Vround .5[slab,flare],90);
  60.  rt x11=hround(r-letter_fit-u); bot y11l=vround .07bar_height-o;
  61.  filldraw stroke term.e(10',11,right,1,4); fi  % terminal
  62. penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
  63.  
  64. ecchar "Question mark";
  65. beginchar("?",8.5u#,asc_height#,0);
  66. italcorr .8asc_height#*slant;
  67. adjust_fit(0,0);
  68. pickup tiny.nib; pos7(dot_size,0); pos8(dot_size,90);
  69. lft x7l=hround(.5w-.25u-.5dot_size); bot y8l=0; z7=z8; dot(7,8);  % dot
  70. numeric bot_width;
  71. bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
  72. pickup fine.nib; pos2(vair,90); pos3(curve,0);
  73. pos4(vair,-90); pos5(bot_width,0); pos6(bot_width,0);
  74. x2=x4=x5=x6=x7; rt x3r=hround(w-u); bot y6=1+.25[top y8r,x_height];
  75. top y2r=h+oo; y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
  76. {{interim superness:=more_super;
  77. filldraw stroke pulled_super_arc.e(2,3)(superpull)
  78.  & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}};  % arc and stem
  79. if serifs: pos1(hair,180); pos0(flare,180);
  80.  lft x1r=hround u; y1=y3; bulb(2,1,0);  % bulb
  81. else: pos1(Vround 5/7[vair,flare],110);
  82.  lft x1r=hround u; top y1r=vround .9[y6,top y2r];
  83.  filldraw stroke term.e(2,1,left,1,4); fi  % terminal
  84. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  85.  
  86. ecchar "Spanish open question mark";
  87. beginchar(oct"276",8.5u#,asc_height#-desc_depth#,desc_depth#);
  88. adjust_fit(0,0);
  89. pickup tiny.nib; pos7(dot_size,0); pos8(dot_size,90);
  90. lft x7l=hround(.5w-.25u-.5dot_size); top y8r=h; z7=z8; dot(7,8);  % dot
  91. numeric top_width;
  92. top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
  93. pickup fine.nib; pos2(vair,270); pos3(curve,180);
  94. pos4(vair,90); pos5(top_width,180); pos6(top_width,180);
  95. x2=x4=x5=x6=x7; lft x3r=hround u; top y6=.25[bot y8l,h-x_height]-1;
  96. bot y2r=-d-oo; y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
  97. {{interim superness:=more_super;
  98. filldraw stroke pulled_super_arc.e(2,3)(superpull)
  99.  & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}};  % arc and stem
  100. if serifs: pos1(hair,0); pos0(flare,0);
  101.  rt x1r=hround(w-u); y1=y3; bulb(2,1,0);  % bulb
  102. else: pos1(Vround 5/7[vair,flare],-70);
  103.  rt x1r=hround(w-u); bot y1r=vround .9[y6,bot y2r];
  104.  filldraw stroke term.e(2,1,right,1,4); fi  % terminal
  105. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  106.  
  107. endinput;
  108.